sourceserver.info

Zitat

"Source" konnte nicht gefunden werden. Stellen Sie sicher, dass Sie den Namen richtig eingegeben haben und wiederholen Sie den Vorgang.

Zitat

@echo off
rem @2009 sourceserver.inf0
rem Kommentare beginnen mit rem.
rem Mittels set wird die Variable geändert, die zuvor im Kommentar beschrieben wurde.
rem Mit dieser Batchdatei kann ein Server geupdatet und gestartet werden.
rem Stürzt der Server ab, wird er automatisch neu gestartet.
rem Beim ersten Start wird der Server upgedatet
rem Stürzt der Server ab, wird er vor dem neustart erst wieder geupdatet.
rem Die Batchdatei kann auch für die Installation des Servers verwendet werden.
rem Zuvor muss aber das Verzeichnis des Server angelegt werden und hldsupdatetool.exe muss
rem erfolgreich installiert sein.


rem
rem Die folgenden Variablen müssen alle angepasst werden.
rem


rem Verzeichnis des Gameservers
set server=C:\Server\Gameserver\CSSPublic\

rem Verzeichnis in dem sich hldsupdatetool.exe befindet.
rem Es ist sinnvoll den Server selbst in ein anderes Verzeichnis zu installieren.
rem Für Windos gibt es keine eigene Autoupdatefunktion
set hldsupdatetool=C:\Server\Gameserver\CSSPublic\

rem Modifikation, die geupdatet werden soll
rem CS:S = "Counter-Strike Source"
rem Team Fortress 2 = tf (keine 2 am Ende)
rem Half-Life 2 Deathmatch = hl2mp
rem Day of Defeat Source = dods
rem Left 4 Dead = left4dead
set modupdate="Counter-Strike Source"

rem IP vom Server, localhost sollte im LAN reichen.
set ip=192.168.178.29

rem Port des Servers
rem 27015 ist der Standardport
set port=27015


rem Verzeichnis der Modifikation
rem CS:S = cstrike
rem Team Fortress 2 = tf
rem Half-Life 2 Deathmatch = hl2mp
rem Day of Defeat Source = dod (kein s am Ende)
rem Left 4 Dead = left4dead
set modserver=cstrike

rem verfügbare Plätze für Spieler
set maxplayers=32

rem Das übergeordnete Verzeichnis der Modifiktaion
rem Dort befindet sich die srcds.exe
rem Source/EP1-Engine (Counter-Strike: Source) = %server%
rem OrangBox Engine (tf2, synergy, zps usw.) = %server%\orangebox
rem L4D Engine (zZ. nur Left 4 Dead) = %server%\l4d
set daemondir=%server%

rem Ausfürhbare Datei, mit dem der Server gestartet wird
rem srcds.exe wird bei allen Mods der Source Engine verwendet
set deamonexec=srcds.exe

rem Map, mit der der Server gestartet wird
set startmap=de_dust

rem Tickrate des Servers
rem Bei CS:S ist TR 33 Standard, bei allen anderen Mods ist TR 66 Standard
rem Bei Left 4 Dead kann die Tickrate nicht gesetzt werden. Der Server ignoriert den Parameter einfach.
set tickrate=100

rem Zusätzliche Parameter:
rem Für LAN-Server -> -nomaster -insecure +sv_lan 1
rem Zusätzlich sollte -nocrashdialog verwendet werden, damit bei einem Absturz keine Fehlermeldung kommt,
rem die weggeklickt werden muss.
rem Zusätzlich können noch andere Startoptionen/-parameter verwendet werden
set parm=-nocrashdialog


rem
rem /////// Programm fängt hier an /////////
rem
title Restartscript - Server: %server% Mod: %modserver%
echo (%date% - %time%) Batchdatei gestartet

:start
echo Serverupdate... %server%
start "Fuehre Serverupdate aus: %server% Game: %modupdate%" /wait /MIN /D %hldsupdatetool% %hldsupdatetool%\HldsUpdateTool.exe -command update -game "%modupdate%" -dir "%server%"

echo (%date% - %time%) Starte Server %server%
start /wait /MIN /D %daemondir% %daemondir%\%deamonexec% -game %modserver% -maxplayers %maxplayers% -console -ip %ip% -port %port% -tickrate %tickrate% +map %startmap% %parm%

echo (%date% - %time%) Server ist abgestuerzt. Automatisches Update wird gestartet...
goto start